***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Nov. 25, 2024                                                        *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   PJQ4548VP-AU     drain  gate  source
Lg     gate  g1    2.2n
Ld     drain d1    100p
Ls     source s1   350p
Rs      s1    s2   205u TC=3m
Rg     g1    g2     1.337
M1      d2    g2    s2    s2    DMOS    L=1u   W=1u
.MODEL DMOS NMOS ( KP=122.2  VTO=3.87  LEVEL=3  VMAX=5e4  ETA=0.006  nfs=8.042e11  gamma=1.27)
Rd     d1    d2    6.31e-3    TC=4.95e-3,1.115e-5
Dbd     s2    d2    Dbt
.MODEL   Dbt   D(BV=44  TBV1=6.195e-4 TBV2=1.905e-7  CJO=6.285e-10  M=1.325  VJ=11.519)
Dbody   s2   21    DBODY
.MODEL DBODY  D(IS=6.319e-13  N=1.013  RS=4e-8  EG=1.13  TT=20n IKF=27.242 tikf=1e-6)
Rdiode  d1  21    3.294e-3 TC=2.5e-3
.MODEL   sw    NMOS(VTO=0  KP=10   LEVEL=1)
Maux      g2   c    a    a   sw
Maux2     b    d    g2    g2   sw
Eaux      c    a    d2    g2   1
Eaux2     d    g2   d2    g2   -1
Cox       b    d2   1.33e-10
.MODEL     DGD    D(cjo=1.362e-10   M=0.803   VJ=3.801)
Rpar      b    d2   10Meg
Dgd       a    d2   DGD
Rpar2     d2   a    10Meg
Cgs     g2    s2    6.215e-10
.ENDS PJQ4548VP-AU
*$
